Độ biến động được tính như thế nào trong Bộ lọc?

Sự biến động đo lường sự thay đổi giá của một công cụ tài chính trong một khoảng thời gian xác định. Phạm vi giá càng rộng thì mức biến động càng cao. Phạm vi giá càng hẹp, độ biến động càng thấp.

Đây là công thức tính biến động mà chúng tôi sử dụng để tính toán (hàng tuần, hàng tháng và hàng ngày):

//@version=4
study("volatility")

fastSearchN(xs, x) => // xs - sorted, ascending
    max_bars_back(xs, 366)
    left  = 0
    right = min(bar_index,366)
    mid = 0
    if xs < x
        0
    else
        for i = 0 to 9
            mid := ceil((left+right) / 2)
            if left == right
                break
            else if xs[mid] < x
                right := mid
                continue
            else if xs[mid] > x
                left := mid
                continue
            else
                break
        mid

month1 = 30
month_ago = timenow - 1000*60*60*24*month1
month_ago_this_bar = time - 1000*60*60*24*month1
countOfBars1MonthAgo = fastSearchN(time, month_ago)
countOfBars1MonthAgoThisBar = fastSearchN(time, month_ago_this_bar)

week1 = 7
week_ago = timenow - 1000*60*60*24*week1
week_ago_this_bar = time - 1000*60*60*24*week1
countOfBarsWeekAgo = fastSearchN(time, week_ago)
countOfBarsWeekAgoThisBar = fastSearchN(time, week_ago_this_bar)

// volatility
volatility(bb) =>
    bb2 = bb
    if bar_index == 0
        bb2 := 365
    if bb2 == 0
        na
    else
        s = sum((high-low)/abs(low) * 100 / bb2, bb2)
        if bb == 0
            na
        else
            s

plot(volatility(countOfBarsWeekAgoThisBar), title="Volatility.W")
plot(volatility(countOfBars1MonthAgoThisBar),title="Volatility.M")
plot(tr(true)*100/abs(low), title="Volatility.D")

Lưu ý: giá trị tập lệnh này khác nhau trên lịch sử và thời gian thực do thời gian biết, hãy xem https://www.tradingview.com/pine-script-docs/en/v4/essential/Indicator_repainting.html

Để hiển thị trực quan, bạn có thể thêm tập lệnh này vào biểu đồ của mình thông qua Pine Editor bằng khung thời gian hàng ngày của biểu đồ. Một chỉ báo sẽ xuất hiện trên biểu đồ, các biểu đồ sẽ hiển thị giá trị cho từng loại biến động.